Posting Form Data to E-Mail and XiTouch - Post2EMail.php Source Code

[Home] [Blogs] [XiTouch] [EMILY] [Tools] [Services] [Teach] [Mac] [My Blog] [Contact]

Posting Form Data to E-Mail
Post2EMail.acgi and post2email.php Source Code

Comment: post2email.acgi, which runs natively on the classic MacOS, has reached end-of-life. It has being replaced with post2email.php, which runs natively on Unix systems, such as MacOSX and MacOSX Server. The source code for Post2Email.php is further down this page.

Related Links

As of September 22, 2002, post2email.acgi was at version 0.13b41

(and will stay there in perpetuity)

(* post2email.acgi v0.13b41
   complete information can be found at
   
   http://www.linkedresources.com/tools/post2email/basicfeatures.shtml *)

-- these are the user customizable properties

property webserver: "WebSTAR 4.5"
property mailHost : "mailhost.domain.com"
property mailWatcher : "mailwatcher@domain.com"

-- end user properties

property crlf : (ASCII character 13) & (ASCII character 10)
property http_10_header : "HTTP/1.0 200 OK" & crlf & "Server: " & webserver & crlf & "MIME-Version: 1.0" & crlf & "Content-type: text/html" & crlf & crlf
property http_10_301_header : "HTTP/1.0 301 Moved Permanently" & crlf & "Server: " & webserver & crlf & "MIME-Version: 1.0" & crlf & "Location:"

property redir_header : "HTTP/1.0 301 REDIRECT" & crlf & "Server: " & webserver & crlf & "Location: "

property br : "<br>"
property br2 : "<br><br>"
property hrr : "<hr>" & return
property brr : "<br>" & return
property br2r : "<br><br>" & return
property bbrr : "</b><br>" & return
property bbr2r : "</b><br><br>" & return
property rtn : return
property rtn2 : return & return
-- the following construction prevents email readers from parsing the html (I hope)
property hht : "<ht" & "ml><he" & "ad><ti" & "tle>"
property thr : "</ti" & "tle></he" & "ad>" & rtn
property thb : "</ti" & "tle></he" & "ad>" & rtn & "<bo" & "dy>" & rtn
property bhr : "</bo" & "dy></ht" & "ml>" & return

property basicLookup : {"recipient", "sortOrder", "required", "responsePage", "errorPage", "introLine", "echoBlanks", "fromUserFieldName","except","metaSortOrder"}

property errPageTitle : "An Error Has Occurred"
property cgiErrorHeader : "<h2>A Processing Error Has Occurred</h2>"
property cgiErrorMsg : "Please contact the webmaster at " & mailWatcher & " so this problem can be investigated."
property backButton : "Please also use your browser's [Back] button to try again..."

property defaultRedirect : "http://www.linkedresources.com/services/post2email_redirect.shtml"
property defaultErrorpage : "http://www.linkedresources.com/services/post2email_errorpage.shtml"

property minutesToLive : 2

property lastused : 0

on run
	my resetVars()
end run

on idle
	try
		set lastused to lastused + 1
		if lastused is less than minutesToLive then
			return 60
		else
			my resetVars()
			tell me to quit
		end if
	on error --
	end try
	set lastused to 0
	return 60
end idle

on resetVars()
	set lastused to 0
end resetVars

on handle CGI request URL_path Ā
	searching for searching_for Ā
	with posted data posted_data Ā
	of content type content_type Ā
	using access method access_method Ā
	from address client_address Ā
	from user userName Ā
	using password password Ā
	with user info user_info Ā
	from server server_name Ā
	via port server_port Ā
	executing by script_name Ā
	referred by referred_by Ā
	from browser browser_name Ā
	using action action_used Ā
	of action type action_type Ā
	from client IP address client_IP_address Ā
	with full request full_request Ā
	with connection ID connection_ID
	
	try
		-- set posted_dataX to my removeString("%0A", posted_data)
		set postedData to my parseCGIargs(posted_data)
		
		set formMemorySavvy to my ACMElookup("helper_recipient", postedData)
		
		if formMemorySavvy is equal to "" then
			set {recipient, sortOrder, requiredFields, redirect, errorpage, introLine, echoBlanks, fromUserFieldName,dontInclude,metaSortOrder} to my lookupCGIfields(basicLookup, postedData, "")
		else
			set helperLookup to {}
			repeat with aLookup in rest of basicLookup
				set x to "helper_" & aLookup
				copy x to end of helperLookup		
			end repeat
			set recipient to formMemorySavvy	
			set {sortOrder, requiredFields, redirect, errorpage, introLine, echoBlanks, fromUserFieldName,dontInclude,metaSortOrder} to my lookupCGIfields(helperLookup, postedData, "")
		end if
		
		-- added Sept 20, 2002
		set recipient to my analyzeRecipient(recipient,postedData)		
		
		-- this is tricky. post2email developed 2 forks. In one, echoBlanks was true, in the other, it was "true"
		-- I will settle on "true", but this fork used true, so there may be odd behaviors
		-- the commented line is the original for this script
		-- if echoBlanks is equal to "" or echoBlanks is equal to "true" then set echoBlanks to true
		if echoBlanks is equal to "" then set echoBlanks to "true"
		
		set fromUser to my lookupCGIfield(fromUserFieldName, postedData)
		if fromUser is equal to "" then set fromUser to "inquiry@" & mailHost
		
		-- for backward compatability and error trapping
		set script_messages to ""
		if introLine is equal to "" then
			set introLine to my lookupCGIfield("subject", postedData)
		end if
		if introLine is equal to "" then
			set introLine to "Form Submission from " & fromUser
		end if
		
		if redirect is equal to "" then set redirect to defaultRedirect
		if errorpage is equal to "" then set errorpage to defaultErrorpage

if sortOrder as text is equal to "" then
			set sort_order to my lookupCGIfield("sort", postedData)
			if sort_order as text is equal to "" then
				if dontinclude is equal to "" then
					set allFields to {}
					repeat with fieldValuePair in postedData
						set fieldname to (item 1 of fieldValuePair) as string
						if fieldname is not in basicLookup then
							if text 1 thru 7 of fieldname is not equal to "helper_" then
								copy fieldname to end of allFields
							end if
						end if
					end repeat
					set sortOrder to my listToString(allFields, ",")
					set echoBlanks to "true"
					set next_script_message to "No sort order was specified, so all non-admin fields were passed." & rtn2
					set script_messages to script_messages & next_script_message
				end if
			else
				try
					set x to my powersplit(sort_order, {":"})
					set sortOrder to item -1 of x
					set sort_param to item 1 of x
					if sort_param is not in {"order", sortOrder} then
						set next_script_message to "The sort parameter I received was " & sort_param & ". Is this correct?" & rtn2
						set script_messages to script_messages & next_script_message
					end if
				on error errmsg
					set script_messages to script_messages & " while analyzing sortOrder I got this error: " & errmsg
					set sortOrder to ""
					set sort_param to ""
				end try
			end if
		else if sortOrder is equal to "_meta" then
			set metaSortOrder to my powersplit(metaSortOrder, {","})
			set sortOrder to {}
			repeat with partialOrder in metaSortOrder
				set partialSortOrder to my lookupCGIfield(partialOrder, postedData)
				copy partialSortOrder to end of sortOrder
			end repeat
			set sortOrder to listToString(sortOrder, ",")
		end if

set sortOrder to my powersplit(sortOrder, {","})
		
		try
			set requiredFields to my powersplit(requiredFields, {","})
			set requiredOK to my verifyRequiredFields(requiredFields, postedData)
		on error errmsg
			set requiredOK to true
			set script_messages to script_messages & " while checking requiredFields I got this error: " & errmsg
		end try
		
		if requiredOK then
			if dontInclude is equal to "" then
				set echoBack to my rawdata(postedData, sortOrder, echoBlanks) -- just echoes back the submitted data in order
			else
				set echoBack to my rawdata(postedData, dontInclude, "except")
			end if

set subjectText to introLine
			set msgText to (introLine & rtn2 & script_messages & echoBack) as string
			my sendMail(mailHost, fromUser, recipient, "", mailWatcher, subjectText, msgText)
		else
			set redirect to errorpage
		end if
		set newhtml to redir_header & redirect & crlf & crlf
		-- set newhtml to http_10_header & hht & "test" & thr & msgText & bhr
		return newhtml
	on error errmsg
		set newhtml to (http_10_header & hht & errPageTitle & thb & cgiErrorHeader & errmsg & cgiErrorMsg & backButton & bhr) as string
		return newhtml
	end try
end handle CGI request

on removeString(outString, theString)
	set safeString to theString
	try
		set oldDelims to AppleScript's text item delimiters
		set AppleScript's text item delimiters to outString
		set tempstring to text items of theString
		set AppleScript's text item delimiters to ""
		set trimmedString to tempstring as string
		set AppleScript's text item delimiters to oldDelims
		return trimmedString
	on error
		try
			set AppleScript's text item delimiters to oldDelims
		on error
			set AppleScript's text item delimiters to ""
		end try
	end try
	return safeString
end removeString

on replaceString(src, oldString, newString)
	set newsrc to src
	try
		set oldDelims to AppleScript's text item delimiters
		set AppleScript's text item delimiters to oldString
		set srcList to text items of src as list
		set AppleScript's text item delimiters to newString
		set newsrc to srcList as string
		set AppleScript's text item delimiters to oldDelims
	on error
		try
			set AppleScript's text item delimiters to oldDelims
		on error
			set AppleScript's text item delimiters to {""}
		end try
	end try
	return newsrc
end replaceString

on parseCGIargs(thePost)
	set parsedArgs to {}
	try
		set parsedArgs to MT Parse CGI thePost with field name
	on error
		try
			set parsedArgs to ACME parse args thePost
		on error --
		end try
	end try
	return parsedArgs
end parseCGIargs

on lookupCGIfield(theField, thePost)
	set fieldValue to ""
	set theField to theField as string
	try
		if theField is in (thePost as string) then
			repeat with k from 1 to (length of thePost)
				if ((item 1 of (item k of thePost)) as string) is equal to theField then
					copy ("" & (item 2 of (item k of thePost))) to fieldValue -- force to string in all cases
					return fieldValue
				end if
			end repeat
		end if
	on error --
	end try
	return fieldValue
end lookupCGIfield

on lookupCGIfields(desiredFields, parsedPost, defaultValue)
	set fieldValues to {}
	repeat with desiredField in desiredFields
		set fieldValue to my lookupCGIfield(desiredField, parsedPost)
		if fieldValue is equal to "" then copy defaultValue to fieldValue
		copy fieldValue to end of fieldValues
	end repeat
	return fieldValues
end lookupCGIfields

on stringToList(theString, delim)
	set astidold to AppleScript's text item delimiters
	set AppleScript's text item delimiters to {delim}
	set listData to (text items of theString) as list
	set AppleScript's text item delimiters to astidold
	return listData
end stringToList

on listToString(theList, newDelim)
	set newString to ""
	try
		set oldDelims to AppleScript's text item delimiters
		set AppleScript's text item delimiters to newDelim
		set newString to theList as string
		set AppleScript's text item delimiters to oldDelims
	on error
		try
			set newString to theList as string
			set AppleScript's text item delimiters to oldDelims
		on error
			set AppleScript's text item delimiters to {""}
		end try
	end try
	return newString
end listToString

on powersplit(src, delimList)
	-- set newDelim to (item 1 of delimList) as string
	set newDelim to {(item 1 of delimList) as string}
	if length of delimList is equal to 1 then
		set srcAsList to {}
		try
			set oldDelims to AppleScript's text item delimiters
			set AppleScript's text item delimiters to newDelim
			set srcAsList to (text items of src) as list
			set AppleScript's text item delimiters to oldDelims
		on error
			try
				set AppleScript's text item delimiters to oldDelims
			on error
				set AppleScript's text item delimiters to {""}
			end try
		end try
		return srcAsList
	else
		set linesAsList to {}
		set srcAsList to my powersplit(src, newDelim)
		repeat with aLine in srcAsList
			set aLineAsList to my powersplit(aLine, (rest of delimList))
			copy aLineAsList to end of linesAsList
		end repeat
		return linesAsList
	end if
end powersplit

on verifyRequiredFields(theFields, parsedData)
	if theFields as string is equal to "" then return true
	set isOK to true
	try
		repeat with aField in theFields
			set x to my lookupCGIfield(aField, parsedData) -- ACME lookup field aField in parsedData default value ""
			if x as text is equal to "" then set isOK to false
		end repeat
	on error errmsg
		set isOK to false
	end try
	return isOK
end verifyRequiredFields

-- this is the version which combines the best elements of the above versions of rawdata
on rawdata(parsedData, sortOrder, echoBlanks)
	set theEcho to {}
	if sortOrder is equal to {} then
		repeat with aPair in parsedData
			set thisField to ((item 1 of aPair) as string)
			set fv to my ACMElookup(thisField, parsedData)
			if fv is not equal to "" or echoBlanks is equal to "true" then
				copy (thisField & " = " & fv) to end of theEcho
			end if
		end repeat
	else
		if echoBlanks is equal to "except" then
			repeat with aPair in parsedData
				set thisField to ((item 1 of aPair) as string)
				if thisField is not in sortOrder then
					copy (thisField & " = " & (item 2 of aPair)) to end of theEcho
				end if
			end repeat
		else
			repeat with aField in sortOrder
				set thisField to (aField as string)
				if thisField is not equal to "" then
					set fv to my ACMElookup(thisField,parsedData)
					if fv is not equal to "" or echoBlanks is equal to "true" then
						copy (thisField & " = " & fv) to end of theEcho
					end if
				end if
			end repeat
		end if
	end if
	set theEcho to listToString(theEcho, return)
	return theEcho
end rawdata

on ACMElookup(thisField, parsedData)
	set fieldValue to ""
	try
		-- use ACME Script Widgets if they are available
		set fieldValue to ACME lookup field thisField in parsedData
	on error
		set fieldValue to my lookupCGIfield(thisField, parsedData)
	end try
	set fieldValue to fieldValue as string
	return fieldValue
end ACMElookup

on sendMail(mHost, mFrom, mTo, mCC, mBCC, mSubject, mBody)
	my startApp("@CME") -- Mondo Mail.fat	
	try
		tell application "Mondo Mail.fat"
			send mail mBody subject mSubject to mTo CC mCC BCC mBCC from mFrom SMTP gateway mHost
		end tell
	on error msg number eNum
		delay 2
		try
			tell application "Mondo Mail.fat"
				send mail mBody subject mSubject to mTo CC mCC BCC mBCC from mFrom SMTP gateway mHost
			end tell
		on error --
		end try
	end try
end sendMail

on startApp(creaType)
	try
		tell application "Finder"
			tell application file id creaType
				open
			end tell
		end tell
	on error --
	end try
end startApp

on analyzeRecipient(recip,thePost)
		
	-- deal with absent value
	if recip is equal to "" then set recip to mailWatcher
	
	-- improve compatibility with FormMemory
	if recip is equal to "helper_recipient" then
		set recip to my ACMElookup("helper_recipient", thePost)
	end if
	
	-- improve spam blocking capabilities
	set recip to my replaceString(recip, "_p2em_", "")
	set recip to my replaceString(recip, "(shift-2)", "@")
	set recip to my replaceString(recip, "(dot)", ".")
	set recip to my replaceString(recip, "(period)", ".")
	
	set {spamblockfrom,spamblockto} to my lookupCGIfields({"helper_spamblockfrom","helper_spamblockto"},thePost,"whatever")
	set recip to my replaceString(recip, spamblockfrom, spamblockto)

return recip

end analyzeRecipient

-- if you are seeing this first, scroll back to the top

As of October 30, 2004, post2email.php is at version 0.24b4

(and is being actively developed based on user feedback)

// post2email.php version 0.24b4

// configurable vars
$runningAt = "216.250.186.147";
$mailHost = "mail3.linkedresources.com";
$mailWatcher = "mailwatcher@linkedresources.com";
$defaultURLbase = 'http://www.linkedresources.com/services/';
$defaultRedirect = $defaultURLbase.'post2email_redirect.shtml';
$defaultErrorpage = $defaultURLbase.'post2email_errorpage.shtml';
$defaultFromAddress = "post2email@linkedresources.com";
$adminFields = array("recipient", "sortOrder", "required", "responsePage", "errorPage", "introLine", "echoBlanks","suppressFieldnames","fromUserFieldName", "except","metaSortOrder","debug","formName");
$templateroot='';

// mySQL vars
$suppressDB = 'true';  // change to false to save data to XiTouch
$host_name = 'localhost';
$mysql_user = "post2email_i";
$mysql_pass = "pickyourown";
$db_name = "xitouch";
$tbl_name = "post2email";

/* ---------------------- functions block ------------------------------*/

function analyzeRecipient($recip) {
	global $debug_messages;
	$debug_messages.="recipient at start of analyzeRecipient is $recip <br>\r";
	
	// deal with absent value
	global $mailWatcher;
	if ($recip=="") {
		$recip = $mailWatcher;
		}
	
	// improve compatibility with FormMemory
	if($recip=="helper_recipient") {
		global $helper_recipient;
		$recip=$helper_recipient;
		}

// improve spam blocking capabilities
	$recip=str_replace("_p2em_","",$recip);
	$recip=str_replace("(shift-2)","@",$recip);
	$recip=str_replace("(at)","@",$recip);
	$recip=str_replace("(dot)",".",$recip);
	$recip=str_replace("(period)",".",$recip);

$debug_messages.= "recipient in middle of analyzeRecipient = $recip <br>\r";
	
	global $helper_spamblockfrom;
	global $helper_spamblockto;
	$recip=str_replace($helper_spamblockfrom,$helper_spamblockto,$recip);

$debug_messages.= "recipient at end of analyzeRecipient = $recip <br>\r";
	
	return $recip;
	}

// check required fields
function verifyRequiredFields($reqs) {
	$reqsA = explode(',',$reqs);
	$verified = "true";
	while (list($reqid,$reqf)=each($reqsA)) {
		global $$reqf;
		if (!$$reqf) {
			$verified="false";
			global $debug_messages;
			$debug_messages.="field $reqf was not included.<br>\r";
			}
		}
	return $verified;
	}

// echo back the requested fields
function echoFields($sortOrder,$echoCode) {
	global $suppressFieldnames;
	global $HTTP_POST_VARS;
	global $debug_messages;
	$theEcho = '';
	$debug_messages.="inside the echoFields function now...<br>\r";
	
	if ($sortOrder=='') {
		$debug_messages.="sortOrder is empty...<br>\r";
		while (list($fname,$fvalue)=each($HTTP_POST_VARS)) {
			if ($fvalue!=''||$echoCode=="true") {
				$theEcho.=addData($fname);
				}
			}
		} else {
		$sortOrderArray = explode(",",$sortOrder);
		$debug_messages.="sortOrder is not empty, but is equal to $sortOrder <br>\r";
		$debug_messages.="echoCode is equal to $echoCode <br>\r";
		if ($echoCode=="except") {
			while (list($fname,$fvalue)=each($HTTP_POST_VARS)) {
				if (isNotin($fname,$sortOrderArray)=="true") {
					$theEcho.=addData($fname);
					}
				}
			} else {
			while (list($soid,$fname)=each($sortOrderArray)) {
				global $$fname;
				if ($echoCode=="true"||$$fname) {
					$theEcho.=addData($fname);
					}
				}
			}
		}
	return $theEcho;
	}

/* --------------------- start of main script logic --------------------------*/

extract($_GET); // fields can be passed in the URL
extract($_POST);

// set up debugging
if (!$debug) {
	$debug = $helper_debug;
	}
$debug_messages = "<h3>Debugging messages generated by post2email.php</h3>\r";

// maintain formMemory compatibility
if ($helper_recipient) {
	$debug_messages.="This form is formMemory savvy.<br>\r";
	while (list($ind,$adminFieldName)=each($adminFields)) {
		$x = "helper_".$adminFieldName;
		if($$x) { // helper fields will overwrite "regular" field names
			$$adminFieldName = $$x;
			}
		}
	}

/* -------------------------- set up the smtp object -------------------------*/
require("smtp.php"); // Manuel Lemos' script from www.phpclasses.org
$smtp=new smtp_class;

if(!function_exists("GetMXRR")) {
	$debug_messages.="GetMXRR does not exist.<br>\r";
	$_NAMESERVERS=array();
	include("getmxrr.php");
	} else {
	$debug_messages.="GetMXRR does exist.<br>\r";	
	}

$smtp->host_name=$mailHost; /* relay SMTP server address */
$smtp->localhost=$runningAt; /* this computer address */

$smtp->direct_delivery=0; /* Set to 1 to deliver directly to the recipient SMTP server */
if ($debug=="true") {
	$smtp->debug=1;
	} else {
	$smtp->debug=0; /* Set to 1 to output the communication with the SMTP server */
	}

$smtp->user=""; /* Set to the user name if the server requires authetication */
/* Set to the authentication realm, usually the authentication user e-mail domain */
$smtp->realm=""; 
$smtp->password=""; /* Set to the authentication password */

/* -------------------------- analyze the form data --------------------------------*/
$script_messages = '';
$form_URL = getenv("HTTP_REFERER");
if ($formName) {
	$script_messages.='This data was posted from the form named ';
	$script_messages.=$formName.' located at '.$form_URL.".\r\r";
	} else {
	$script_messages.="This data was posted from a form located at $form_URL .\r\r";
	}

// who are we from?
$from1 = "$fromUserFieldName";
$from = $$from1; 
if (!$from) {
	$from=$defaultFromAddress;
	}
$debug_messages.= 'from = '.$from."<br>\r";

// who are we to?
$to = analyzeRecipient($recipient);
$debug_messages.= "to = $to <br>\r";

// copy to sender?
if ($helper_copy2self=='true') {
	$to = $to.','.$from;
	}

// where are we going?
if (!$responsePage) {
	$responsePage=$defaultRedirect;
	}
$debug_messages.="responsePage is $responsePage <br>\r";
if (!$errorPage) {
	$errorPage=$defaultErrorpage;
	}
$debug_messages.="errorPage is $errorPage <br>\r";

// check required fields
if ($required) {
	$requiredOK = verifyRequiredFields($required);
	} else {
	$requiredOK="true";
	}
$debug_messages.= "required is $requiredOK <br>\r";

// what's our subject?
if (!$introLine) {
	$introLine = $subject;
	}
if (!$introLine) {
	$introLine = 'Form Submission from '.$from;
	if ($formName) {
		$introLine.=" via $formName";
		}
	}
$subject = $introLine;
$debug_messages.= "subject is $subject <br>\r";

/*----------------- parse out sortOrder ---------------------*/
$debug_messages.= "sortOrder before parsing is $sortOrder <br>\r";
if ($sortOrder == "") { // for cross compatibility
	$sortOrder = $sort;
	}
$dontInclude = $except;
if ($sortOrder == ""||$dontInclude!="") {
	if ($dontInclude == "") { // pass all non-admin fields
		$allFields = "";
		$debug_messages.= "Analyzing HTTP_POST_VARS to find the non-admin fields...<br>\r";
		while (list($fname,$fval)=each($HTTP_POST_VARS)) {
			if (isNotin($fname,$adminFields)=="true") {
				if (substr($fname.'.......',0,7)!="helper_") {
					$allFields.=','.$fname;
					}
				}
			}
		$sortOrder = substr($allFields,1); // cuts off leading comma
		$echoBlanks = "true";
		$script_messages.="No sort order was specified, so all non-admin fields were passed.\r\r";
		} else {
		$script_messages.="You have specified to NOT include the fields ($dontInclude).\r\r";
		}
	} elseif ($sortOrder == "_meta") {
	$metaSortOrder1 = explode(",",$metaSortOrder);
	$sortOrder = "";
	while (list($psoID,$partialOrder)=each($metaSortOrder1)) {
		$sortOrder.=','.$$partialOrder;
		}
	$sortOrder = substr($sortOrder,1); // cuts off leading comma
	$script_messages.="You are using the metaSortOrder feature, which is not fully tested.";
	$script_messages.=" Be sure to check the email results carefully.\r\r";
	} else {
	$x = explode(':',$sortOrder); // cross compatbility
	$sort_param = $x[0];
	$debug_messages.="sort_param is $sort_param <br>\r";
	$sortOrder = $x[(count($x)-1)];
	$debug_messages.="sortOrder is $sortOrder <br>\r";
	if ($sort_param!="order"&&$sort_param!=$sortOrder) {	
		$script_messages.="The sort parameter I received was ".$sort_param.'.';
		$script_messages.=" Is this correct?\r\r";
		}
	}
		
if ($sortOrder=="_template") {
	$filename = $templateroot.$templatefile; // eg. "/usr/local/something.txt";
	$handle = fopen($filename, "r");
	$template = fread($handle, filesize($filename));
	fclose($handle);
	}
	
$debug_messages.="sortOrder after parsing is $sortOrder <br>\r";

// formatting stuff
if (!$suppressFieldnames) {
	$suppressFieldnames="false";
	}
if ($suppressFieldnames=="true") {
	$echoBlanks="false"; // makes no sense to echo blanks without a field name
	}

if ($requiredOK=="true") {
	If ($template=='') {
		if ($dontInclude == "") {	// return the requested data fields, in order
			$echoBack = echoFields($sortOrder, $echoBlanks); 
			} else {	// return all fields except those listed in $dontInclude
			$echoBack = echoFields($dontInclude, "except"); 
			}
		$message_body=$script_messages."\r".$echoBack;
		} else {
		$message_body =	useTemplate($template);
		}

$debug_messages.= "<h3>The message body which is being sent</h3>\r<pre>"; 
	$debug_messages.= $message_body."</pre>\r";

if ($debug=="true") {
		echo "<h3>Here are the smtp debugging messages</h3>\r";
		}

if($smtp->SendMessage(
		$from,
		explode(',',$to),
		array(
			"From: $from",
			"To: $to",
			"Subject: $subject",
			"Date: ".strftime("%a, %d %b %Y %H:%M:%S %Z")
		),
		$message_body)) {
		
		if ($debug=="true") {
			echo "<br><br>Message sent to $to OK.<br>\r";
			} else {
			$actualRedirect = $responsePage;
			}
		$successStatus = "sentOK";
	} else {
		if ($debug=="true") {
			echo "<br><br>Could not send the message to $to.<br>Error: ".$smtp->error."<br>\r";
			} else {
			$actualRedirect = $errorPage;
			}
		$successStatus = "NOTsent";
		}
	} else {
	if ($dontInclude == "") {	// return the requested data fields, in order
		$echoBack = echoFields($sortOrder, $echoBlanks); 
		} else {	// return all fields except those listed in $dontInclude
		$echoBack = echoFields($dontInclude, "except"); 
		}

$message_body=$script_messages."\r".$echoBack;

$debug_messages.= "<h3>The message body which is being sent</h3>\r<pre>"; 
	$debug_messages.= $message_body."</pre>\r";

if ($debug=="true") {
		echo "<br><br>Could not send the message - some required field(s) were not included<br>\r";
		} else {
		$actualRedirect = $errorPage;
		}
	$successStatus = "NOTsent";
	}

/* ---------------------- write the data to database -------------------- */
if ($suppressDB!="true") {
	@ $db = mysql_pconnect($host_name, $mysql_user, $mysql_pass);
	if ($db) { 
		mysql_select_db($db_name);
		$record_name = $from;
		if ($formName) {
			$field_left = ':='.$formName.'_'.$successStatus."\r";
			$field_left.= ':='.$formName."\r";
			$field_left.= ':='.$successStatus."\r\r";
			} else {
			$field_left = ':='.$subject.'_'.$successStatus."\r";
			$field_left.= ':='.$subject."\r";
			$field_left.= ':='.$successStatus."\r\r";
			}
			
		$to=explode(',',$to);
		for ($eachto=0;$eachto<count($to);$eachto++) {
			$field_left.=':='.$to[$eachto]."\r";
			}	
		
		$today = date("F j, Y, g:i a");
		
		$field_right = $today."\r".$subject."\r".str_repeat("--",15)."\r".$message_body;
		
		$record_name = addslashes($record_name);
		$field_left = addslashes($field_left);
		$field_right = addslashes($field_right);

$query = 'insert into '.$tbl_name.' values (0,"'.$record_name.'","'.$field_left.'","'.$field_right.'",0)';
		$debug_messages.=$query."<br>\r";
		$inserted = mysql_query($query);
	
		} else {
		$debug_messages.="COULD NOT CONNECT TO THE DATABASE TO STORE THIS MESSAGE!!<br>\r";
		// exit;
		}
	}
/* ---------------------- end mySQL code ----------------------------*/

if ($debug=="true") {
	echo $debug_messages;
	} else {
	header ("Location: ".$actualRedirect);
	}

exit;

-- if you are seeing this first, scroll back to the top

Use these tools at your own risk.

jwbaumann(shift-2)linkedresources(dot)com
----

[Home] [Blogs] [XiTouch] [EMILY] [Tools] [Services] [Teach] [Mac] [My Blog] [Contact]

Posting Form Data to E-MailPost2EMail.acgi and post2email.php Source Code

As of September 22, 2002, post2email.acgi was at version 0.13b41

As of October 30, 2004, post2email.php is at version 0.24b4

Posting Form Data to E-Mail
Post2EMail.acgi and post2email.php Source Code